(2010-04-29) TUTO Mortscript

1° Initiation et Objectifs
2° Les VARIABLES
3° Fonctions Utiles
4° Poser une QUESTION
5° Installation auto SDCARD
6° Installation Silencieuse
7° Base de registre et importation
8° Importation XML
9° Exemple de MSCR
10° Importation PIB fichier PimBackup
11° Script Final (MAJ le 20/04/2010)

---

MAJ du 29/04/2010 :
- Modification SCRIPT final, et fichier .mscr dispo sur demande avec modif ou pas^^
- Installation : créer un dossier AUTO à la racine de votre carte mémoire et à l'intérieur les dossiers suivants

CAB : mettez les cab à installer en auto
EXE : programme à utiliser comme TaskMgr ou PPCPimBackup pr les importations
PIB : mettez vos sauvegardes de pimbackup (contacts, rendez-vous, sms, mms, fichiers etc...)
REG : mettez vos fichiers .reg pour modifier votre base de registre
XML : mettez vos fichiers .provxml pour vos emails et paramétrage wifi!

---

MAJ du 20/04/2010 :
- Simplification de l'installation
- Importation fichier de base de registre .reg
- Importation fichier registre .xml
- MAJ du script final

---

MAJ du 16/03/2010 :
- Ajout de la FONCTION : choicedefault
- MAJ de mon script

---

MAJ du 15/03/2010 :
- Mise en place d'un sommaire pour plus de visibilité
- MAJ du script final par nouvelle méthode plus simple : copie de mon script perso

---

Un p'tit script qui va chercher tous les cabs d'un répertoire pour les exécuter l'un après l'autre...
Utile après un flashage de RUU!!!

ForEach file in Files( "\Carte de stockage\CAB\AUTO\*.cab" )
Runwait( file)
EndForEach

Petite explication:

Tout fichier situé dans le répertoire indiqué, soit \Carte de stockage\CAB\AUTO\ avec l'extension *.cab sera exécuté dans l'ordre grâce à la commande EndForEach

Nota: Pas de soft reset avant la fin du processus complet

Toobaboo a écrit:

Un p'tit script qui va chercher tous les cabs d'un répertoire pour les exécuter l'un après l'autre...
Utile après un flashage de RUU!!!

ForEach file in Files( "\Carte de stockage\CAB\AUTO\*.cab" )
Runwait( file)
EndForEach

Petite explication:

Tout fichier situé dans le répertoire indiqué, soit \Carte de stockage\CAB\AUTO\ avec l'extension *.cab sera exécuté dans l'ordre grâce à la commande EndForEach

Nota: Pas de soft reset avant la fin du processus complet

Alors oui c'est un bon script, je vais en parler MAIS il n'est pas auto car meme si tu as des cabs qui s'installent automatiquement sur mémoire interne, tu es obligé d'appuyer sur OK pour passer au cab suivant...:s
c'est le gros pb de la fonction runwait()
 

SCRIPT : POSER UNE QUESTION :
Ensuite ce qui peut être sympa c'est de rajouter une question, sur certaines rom, des logiciels sont préinstallées, et je voulais gérer cela, donc on utilise :

QUESTION ("Questions à poser", "titre de la fenetre","YesNo") => le 3eme argument ne se touche pas pr ce que l'on veut faire la.

Ex: Installer ou non le cab pr avoir 16 bouton d'actionscreen
=> question("Installer ActionScreen 16 Boutons?","ActioScreen","YesNo")
mais biensur pour que cela soit fonctionnel on le combine à un IF()

If (question("Installer ActionScreen 16 Boutons?","ActioScreen","YesNo"))
ActionScreen = fileexists ("\Windows\Start Menu\Programs\HTCActionScreen.lnk") #vient tester si le logiciel existe déja ou pas ou cas où^^#
if (ActionScreen = 0)
Run ("\" & X & "\App\Skin\HD18ButtonActionScreen_Kwanice.cab")
sleep (5000)
sendleftsoft
Sleep (20000)
sendok
sleep (3000)
endif
EndIf

FONCTION IF()
Donc pour parler un peu de la fonction IF()
Elle permet de réaliser deux actions : une si la condition est réalisée et une autre si elle ne l’est pas J
Donc
IF()
Action à réaliser si condition ok
IFNOT ()
Action à réaliser si condition pas ok
ENDIF
Surtout ne pas l’oublier !!

FONCTION Wait()
Permet de mettre une pause dans le script, je l’utilise notamment pour attendre que l’écran suivant s’affiche ou pour attendre l’installation d’un programme.

FONCTION ForEach file In Files()
Permet de faire une recherche de tous les fichiers en fonction du paramétre
Exemple : rechercher les fichers cab d'un dossier
=> ForEach file In Files ("\storage card\cab auto\*.cab")
NB : existe aussi ForEach file In directories, dans ce cas on va chercher les dossiers.

FONCTION Wceload.exe
C'est ICI
wceload.exe [ /delete | /noui ] [ /confignotify | /nodelete | /safe | /silent | /verifyconfig]
Fonctions utiles : /silent = Supprime les boîtes de dialogue lors de l'installation, et tous Oui / Non. Les messages Oui/non sont par défaut sur 'Oui', sauf si le fichier .cab n'est pas signé. Toutefois, si le fichier .cab n'est pas signé, toutes les fenêtres oui/non seront automatiquement réglées sur 'No' pour des raisons de sécurité, l'installation peut donc échouer.

FONCTION CHOICE et CHOICEDEFAULT
Cette fonction permet de créer une liste d'action.
Dans mes scripts j'utiliserai la fonction Choicedefault car elle permet d'effectuer une action par défaut si aucun choix n'est fait dans la liste.
Donc ca donne
Choicedefaut( "NomdelaPage", "NomdelaFenêtre", N°delactionpardéfaut, tempsenseconde, "Action1", "Action2", "Action3".... )
Case(0)=> en cas d'appuie sur annuler ou si pas d'action
argument
Case(1)
argument
etc...
ENDCHOICE

Importation fichier PIB (PimBackup)

Vous avez l'habitude de sauvegarder vos contacts, rendez-vous, sms avec pimbackup ?
vous voulez automatiser l'importation de vos fichiers PIB ? :p

On va directement lancer l'executable PPCPimBackup avec le fichier de sauvegarde!
bien sur on va mettre ca en script pour qu'il lance vos différents fichiers !

ForEach PIBfile in files (PIB_path)
If ( PIB = 1 )
Else
If (FileExists( "\Windows\PPCPimBackup.exe" )) test si le soft est déjà ds windows
Run("\Windows\PPCPimBackup.exe", PIBFile )
RegWriteDword ( "HKCU", "Kwanice", "PIB", 1 ) on crée un clé de registre pr ne pas faire deux fois cette opération
ElseIf ( FileExists( EXE_path & "\PPCPimBackup.exe" ))
Run( EXE_path & "\PPCPimBackup.exe", PIBFile )
RegWriteDword ( "HKCU", "Kwanice", "PIB", 1 )
EndIf
EndIf
EndForEach[url][/url]

et voila

LES VARIABLES:

Tout d'abord, dans un script on peut déclarer des variables que nous allons utilisé pour nos scripts.

Pour ma part, je voulais automatiser l'exécution des cab, mais comme j'utilise des rom us fallait que je sache si c'est storage card ou carte de stockage.

Faire précéder une ligne de # permet de faire un commentaire, facile pr se rapeler

#Test le nom de la carte de stockage FR ou US
X = regread( "HKLM", "System\StorageManager\Profiles\SDMemory", "folder")

Ensuite dans la perspective d'une automatisation de cab, (et aussi parce que certaines rom CUSTOM ont déjà des programmes pré installés), il fallait que je teste si le programme existe ou pas pour éviter qu'il me le désinstalle ou me fasse une cagade !

Exemple pour le programme CorePlayer, Viewer divx excellent, ca donne =
CorePlayer = fileexists ("\Program Files\CorePlayer\player.exe") OR fileexists ("\" & X & "\Program Files\CorePlayer\player.exe")
=> on va déclarer une variable qui s'appelle "Coreplayer"
=> fileexists teste si le fichier entre parenthése existe ou pas et renvoie 1 si OUI ou 0 si NON
=> direxists ("\Program Files\Coreplayer") va tester si le dossier existe

Maintenant on teste
if (CorePlayer = 0)
Run ("\" & X & "\App\Multimedia\CorePlayer v1.3.6 Build 7427.cab")
=> la fonction IF , si coreplayer est egal à 0, donc en fait si le logiciel n'a pas été installé
=> la fonction RUN, permet de lancer un programme ou un fichier cab, dans mon optique de tout ranger j'ai rangé mes .cab par catégorie

NB : on peut utiliser la fonction RUNWAIT() mais comme mentionné plus bas, celle-ci permet de lancer un programme en attendant la fin de celui-ci. Dans le cas de l'installation d'un cab, celui-ci finit toujours par un OK de confirmation de bonne installation. Avec cette fonction, impossible de passer à la ligne suivante car la fonction RUNWAIT attend la fin de l'éxécution du programme:)

Script à ajouter pour installation automatique sur SD CARD

mouseclick(50,200) (permet de faire un clic pour passer sur l'instal carte mémoire)
sleep (3000)

Bon,
Je vais tenter de vous expliquer les rudiments de mortscript, c'est un logiciel qui permet de lancer des scripts trés puissant sur votre petit bijoux.
Certains s'en servent pour paramétrer leur portable, d'autre pour changer l'orientation de leur téléphone en utilisation GPS avec tom tom ou igo ou autre, d'autre l'utilisent dans la création de leur rom custom => pour vous dire à quel point ce logiciel est utilisé et performant !



Comme bcp ici nous passons notre temps (ma femme la pauvre ! ma femme la pauvre!) sur nos joujoux (oué hiboux genoux etc..), donc ca veut dire flashage rom et donc REINSTALLATION des programmes..:s arf oué c long.. cliquer sur tous les cab etc c'est la misére.
Donc je me suis pkoi pas automatiser tout cela? => mortscript power

Tout d'abord installer mortscript
Site officiel ICI - CAB d'installation version 4.3b15 - Fichier PDF LA



----------------------------------------------------------------------

INITIATION pour les fonctions de base sur Mobile custom (je ne vais pas m'étendre dessus sinon trop long)

------------------------------------------------------------------------

OBJECTIF : Installation automatiquement des fichiers cab qui se situent sur ma carte mémoire, ranger dans différents dossiers (oui j'aime bien les classer, ce qui du coup pr faire une installation auto est plus chiante), soit sur la mémoire interne soit sur ma carte.

[HS : notez qu'il y a aussi la possibilité de venir modifier le fichier cab pour forcer l'installation "en dure" soit sur la mémoire interne soit sur la carte mémoire, je ferai ptet un autre tuto sur ca. Mais parfois ca ne marche pas super donc...]

Comme vous l'avez remarqué, paramétrer ces scripts est long et fastidieux.
Il existe une fonction qui permet d'installer de facon silencieuse (cad en tâche de fond sans vous demandez quoi que ce soit) les .cab.
Il faudra néanmoins faire une distinctions entre les cab qui peuvent être installés tout seul et ceux qui demandent l'intervention de l'utilisateur. Dans ce derniers cas, il faudra utiliser l'ancienne méthode.

Nous allons utilisé deux autres fonctions : ForEach file In Files () et le programme wceload.exe => cf les FONCTIONS

• ForEach file In Files("\" & X & "\App\Auto\*.cab") => rappel : le X est une variable; on demande en quelque sorte de scanner tous les fichiers cab de ce dossier entre ""
  
• RunWait("\Windows\wceload.exe", """" & file & """ /nodelete /silent") => on lance chaque .cab individuellement de facon auto, sans effacer le cab et de facon silencieuse.
  
• EndForEach => fin
  

1° JOUER avec sa base de registre:

- Lire une clé de registre => RegRead( root, Key, Value Name )
- Ecrire => RegWriteString( root, key, Value Name, value ) ou RegWriteDWord ou RegWriteBinary
- Vérifier l'existence d'une clé => RegValueExists( root, key, Value name )
il y a d'autres fonctions je les rajouterai si besoin

root : "HKCU" ou "HKLM" ou "HKCR"
EXEMPLE : RegWriteDWord ( "HKCU", "Kwanice", "Auto_Install", 1 )


2° IMPORTER des fichiers REG:
Il n'existe pas de fonction d'importation de fichier reg avec mortscript. Nous somme obligé d'utiliser un autre programme : TaskMgr.exe qui lui peut importer tout pleins de trucs :p
Il suffit de faire une ligne de code avec comme paramétre le fichier reg à importer
EXEMPLE :
RunWait( "\App\Rom\Perso\FS_TaskMgr.exe", "\App\Rom\Perso\REG\Kwanice_Total_Cmd.reg" & "/silent")
le /silent permet de ne pas avoir de demande de confirmation d'importation:)

et VOILA

1° Script qui désactive le HTC SENSE

tmp=Regread("HKLM","Software\Microsoft\Today\Items\HTC Sense", "Enabled")
if (tmp="0")
RegWriteDWord("HKLM","Software\Microsoft\Today\Items\HTC Sense", "Enabled","1")
Else
RegWriteDWord("HKLM","Software\Microsoft\Today\Items\HTC Sense", "Enabled","0")
Endif
RedrawToday

=> on va lire dans la base de registre l'état des items de la page aujourd'hui
ensuite on la teste et on fait l'inverse, soit on l'active "1" soit on la désactive "0"
la fonction RedrawToday permet de relancer les items de la page aujourd'hui

=> appeler : Switch Htc Sense On-Off.mscr

SCRIPT au 29/04/2010

################################
#TEST le nom de la carte de stockage FR ou US#
###############################
SD = RegRead( "HKLM", "System\StorageManager\Profiles\SDMemory", "folder" )

#########
#VARIABLES#
#########
CAB = RegRead( "HKCU", "Kwanice", "CAB" )
REG = RegRead( "HKCU", "Kwanice", "REG" )
PIB = RegRead( "HKCU", "Kwanice", "PIB" )
CHT = RegRead( "HKCU", "Kwanice", "CHT" )
PROVXML = RegRead( "HKCU", "Kwanice", "PROVXML" )
XML = RegRead( "HKCU", "Kwanice", "XML" )


Max_Manila = RegValueExists( "HKCU", "\Software\HTC\Manila", "Max_Folder" )
Rom_Cooker = RegRead( "HKLM", "Software\OEM", "ROMVersion" )
Co0kie = RegValueExists( "HKCU", "\Software\HTC\Manila", "Co0kie.HomeVersion" )
ActionScreen = FileExists( "\Windows\Start Menu\Programs\Divers\HTCActionScreen.lnk" )
QuickMenu = FileExists( "\Program Files\Quick\Menu\QuickMenu.exe" ) OR FileExists( "\Windows\QuickMenu.exe" )

Googlemaps = DirExists ( "\Program Files\Googlemaps" )

AUTO_path = "\" & SD & "\Auto"
CAB_path = "\" & SD & "\Auto\CAB"
DIV_path = "\" & SD & "\Auto\DIV"
EXE_path = "\" & SD & "\Auto\EXE"
LNK_path = "\" & SD & "\Auto\LNK"
MSCR_path = "\" & SD & "\Auto\MSCR"
PIB_path = "\" & SD & "\Auto\PIB"
REG_path = "\" & SD & "\Auto\REG"
XML_path = "\" & SD & "\Auto\XML"

##############
#INSTALLATION CAB#
##############
If( CAB = 0 )
Callscript( MSCR_path & "\Switch Htc Sense On-Off.mscr" )
Sleep( 2000 )
ForEach file In Files( CAB_path & "\*.cab" )
RunWait( "\Windows\wceload.exe", """" & file & """ /nodelete /silent" )
EndForEach
RegWriteDWord ( "HKCU", "Kwanice", "CAB", 1 )
SleepMessage( 5,"Installation APP Auto ^CR^ OK","C'est pas fini...",0 )
Else
SetChoiceEntryFormat( 30 )
ChoiceDefault( "REINSTALLATION App AUTO?", "Réinstallation APP Auto?", 0, 5, "Oui", "Non" )
Case(0)
SleepMessage( 5,"Réinstallation APP Auto ^CR^ PAS OK","C'est pas fini...",0 )
Case(1)
Callscript( MSCR_path & "\Switch Htc Sense On-Off.mscr" )
Sleep( 2000 )
ForEach file In Files( CAB_path & "\*.cab" )
RunWait( "\Windows\wceload.exe", """" & file & """ /nodelete /silent" )
EndForEach
Callscript( MSCR_path & "\Switch Htc Sense On-Off.mscr" )
Sleep( 2000 )
SleepMessage( 5,"Réinstallation APP Auto ^CR^ OK","C'est pas fini...",0 )
EndChoice
EndIf

If( Co0kie = 0 )
Callscript( MSCR_path & "\Switch Htc Sense On-Off.mscr" )
Sleep( 2000 )
RunWait( "\Windows\wceload.exe", """" & "\" & SD & "\App\Skin\Co0kie.HomeTab_v1.7.1_Kwanice.cab" & """ /nodelete /silent" )
RunWait( "\Windows\wceload.exe", """" & "\" & SD & "\App\Skin\CHTEditor.v1.7.1.1_Kwanice.cab" & """ /nodelete /silent" )
Callscript( MSCR_path & "\Switch Htc Sense On-Off.mscr" )
Sleep( 2000 )
EndIf

If( Googlemaps = 0 )
RunWait( "\" & SD & "\App\Gps\GoogleMaps v.4.1.0_Kwanice.cab" )
EndIf

##############
#INSTALLATION DIV#
##############
If ( CHT = 0 )
RunWait( DIV_path & "\Cookies.cht" )
RegWriteDword ( "HKCU", "Kwanice", "CHT", "1")
EndIf

##############
#INSTALLATION LNK#
##############
If( FileExists("\Windows\Start Menu\Programs\Group SMS.lnk" ) )
Move( "\Windows\Start Menu\Programs\Group SMS.lnk","\Windows\Start Menu\Programs\Com",TRUE,TRUE )
EndIf

If( FileExists("\Windows\Start Menu\Programs\Group MMS.lnk" ) )
Move( "\Windows\Start Menu\Programs\Group MMS.lnk","\Windows\Start Menu\Programs\Com",TRUE,TRUE )
EndIf

If( FileExists( "\Windows\Start Menu\Programs\Shazam.lnk" ) )
Move( "\Windows\Start Menu\Programs\Shazam.lnk","\Windows\Start Menu\Programs\Multimedia",TRUE,TRUE )
EndIf

If( FileExists( "\Windows\Start Menu\Programs\Skyfire.lnk" ) )
Move( "\Windows\Start Menu\Programs\Skyfire.lnk","\Windows\Start Menu\Programs\Internet",TRUE,TRUE )
EndIf

If( FileExists( "\Windows\Start Menu\Programs\Tools\USB To PC.lnk" ) )
Else
Copy( LNK_path & "\USBToPC.lnk", "\Windows\Start Menu\Programs\Tools\USB To PC.lnk" )
EndIf

If( FileExists( "\Windows\Start Menu\Programs\Divers\Switch Sense PB On-Off.lnk" ) )
Else
CreateShortcut( MSCR_path & "\Switch Sense PB On-Off.mscr", "\Windows\Start Menu\Programs\Divers\Switch Sense PB On-Off.lnk" )
EndIf

##############
#INSTALLATION PIB#
##############
ForEach PIBfile in files (PIB_path)
If ( PIB = 1 )
Else
If (FileExists( "\Windows\PPCPimBackup.exe" ))
Run("\Windows\PPCPimBackup.exe", PIBFile )
RegWriteDword ( "HKCU", "Kwanice", "PIB", 1 )
ElseIf ( FileExists( EXE_path & "\PPCPimBackup.exe" ))
Run( EXE_path & "\PPCPimBackup.exe", PIBFile )
RegWriteDword ( "HKCU", "Kwanice", "PIB", 1 )
EndIf
EndIf
EndForEach

##############
#INSTALLATION REG#
##############
If( REG = 0 )
Delete( REG_path & "\1Kwanice_REG_Total.reg" )
ForEach file In Files( REG_path & "\*.reg" )
Kwanice_REG_Total = ReadFile( file )
WriteFile ( REG_path & "\1Kwanice_REG_Total.reg", Kwanice_REG_Total ,1 ,0 )
EndForEach
RunWait( EXE_path & "\FS_TaskMgr.exe", REG_path & "\1Kwanice_REG_Total.reg" )
Callscript( MSCR_path & "\Kwanice email.mscr" )
Sleep( 5000 )
RegWriteDWord ( "HKCU", "Kwanice", "REG", 1 )
Callscript( MSCR_path & "\Switch Htc Sense On-Off.mscr" )
Sleep( 2000 )
SleepMessage( 5,"Importation REG ^CR^ OK","C'est bientôt fini...",0 )
Else
SetChoiceEntryFormat( 30 )
ChoiceDefault( "REINSTALLATION REG?","REINSTALLATION REG?" , 0, 5, "Oui", "Non" )
Case(0)
SleepMessage( 5,"Réimportation REG ^CR^ PAS OK","C'est bientôt fini...",0 )
Case(1)
Query = Input( "1 pr all sinon choix", "Import", 0, 0, "1-Autre" )
If( Query eq "1" )
Callscript( MSCR_path & "\Switch Htc Sense On-Off.mscr" )
Sleep( 2000 )
Delete( REG_path & "\2Kwanice_REG_Query.reg" )
ForEach file In Files( REG_path & "\*.reg" )
Kwanice_REG_Query = ReadFile( file )
WriteFile ( REG_path & "\2Kwanice_REG_Query.reg", Kwanice_REG_Query ,1 ,0 )
EndForEach
RunWait( EXE_path & "FS_TaskMgr.exe", REG_path & "\2Kwanice_REG_Query.reg" )
Callscript( MSCR_path & "\Switch Htc Sense On-Off.mscr" )
Sleep( 2000 )
SleepMessage( 5,"REimportation All REG ^CR^ OK","C'est bientôt fini...",0 )
ElseIf( Query eq "" )
SleepMessage( 5,"REimportation ^CR^ PAS OK","C'est bientôt fini...",0 )
Else
Callscript( MSCR_path & "\Switch Htc Sense On-Off.mscr" )
Sleep( 2000 )
Delete( REG_path & "\2Kwanice_REG_Query.reg" )
ForEach file In Files( REG_path & "\Reg\*" & Query & ".reg" )
Kwanice_REG_Query = ReadFile( file )
WriteFile( REG_path & "\2Kwanice_REG_Query.reg", Kwanice_REG_Query ,1 ,0 )
EndForEach
RunWait( EXE_path & "\FS_TaskMgr.exe", REG_path & "\2Kwanice_REG_Query.reg" )
Callscript( MSCR_path & "\Switch Htc Sense On-Off.mscr" )
Sleep( 2000 )
SleepMessage( 5,"REimportation " & QUERY & " REG ^CR^ OK","C'est bientôt fini...",0 )
EndIf
EndChoice
EndIf

##################
#INSTALLATION PROVXML#
##################
ForEach PROVXMLfile in files ( PROVXML_path )
If ( PROVXML = 1)
Else
RunWait( EXE_path & "\FS_TaskMgr.exe", "/provxml " & PROVXMLfile)
RegWriteDword ( "HKCU", "Kwanice", "PROVXML", 1 )
EndIf
EndForEach

#############
#RUN PROGRAMME#
#############
Run( "\Windows\Start Menu\Programs\Divers\QMenu.lnk" )
Sleep( 2000 )
SendOK
Sleep( 1000 )

#######
#REBOOT#
#######
If( Question( "Installation finie ^CR^Redémarrer TP2?","Reset","YesNo" ) )
Reset
EndIf

Même principe que pour les .reg on utilise le tit programme TaskMgr.exe.

on oublie pas d'utiliser ce tit soft : ProvXML

EXEMPLE :

RunWait( "\" & X & "\App\Rom\Perso\FS_TaskMgr.exe", "/provxml " & "\" & X & "\App\Rom\Perso\XML\Email.provxml" )

On ajout le paramétre /Provxml et voila

Mise à jour du SCRIPT bcp plus simple à utiliser ^^

Coucou,

Merci pour ce tuto mais j'ai une petite question un peu conne

Est-il possible d'exécuter un script MSCR via un CAB ?
J'ai vu qu'il fallait inclure le "setup.dll" mais cela oblige-t-il d'utiliser WinCE Cab Manager ?

Merci par avance pour vos réponses.
Cdt,
Nino